La maison du fou gwbasic

Index › Forums › English-speaking section › Forums A.I. – Press and news › Tips and Tricks for the Microsoft AI Assistant › La maison du fou gwbasic

Tagged: ,

  • This topic is empty.
Viewing 1 post (of 1 total)
  • Author
    Posts
  • April 30, 2026 at 1:32 pm #19141
    admin
    Keymaster
      Up
      0
      Down
      ::

      🎮 How to Run a .BAS Game (La Maison du Fou) on a Modern PC

      This guide explains how to run the classic BASIC game La Maison du Fou on any modern Windows PC using DOSBox and GW-BASIC.

      ✅ Step 1 — Download DOSBox

      Download DOSBox from the official website:

      https://www.dosbox.com/download.php

      ✅ Step 2 — Get GW-BASIC

      You need the interpreter GWBASIC.EXE. Place it somewhere safe on your PC.

      ✅ Step 3 — Create a Working Folder

      Create a folder on your PC, for example:

      C:\gwbasic

      Put inside this folder:

      • GWBASIC.EXE
      • MAISON.BAS (your game)

      Your folder should look like:

      C:\gwbasic\GWBASIC.EXE
C:\gwbasic\MAISON.BAS

      ✅ Step 4 — Start DOSBox

      Open DOSBox and type the following commands:

      mount c c:\gwbasic
c:

      You are now inside your working folder.

      ✅ Step 5 — Launch GW-BASIC

      gwbasic

      ✅ Step 6 — Load and Run the Game

      load "maison.bas"
run

      🎉 The game starts and you can play La Maison du Fou exactly like in 1984.

      🧩 Useful Commands

      list      (view the BASIC code)
system    (exit GW-BASIC)
exit      (quit DOSBox)

      🎉 You’re Ready to Play

      This method is stable, authentic, and works with any BASIC game.

      10 REM ***********************************************
      12 REM MAISON DU FOU – PROGRAMME BASIC
      13 REM
      14 REM Auteurs : DIEUDONNE P. NOEL H.
      15 REM Magazine MICRO 7 mars 1984
      16 REM
      17 REM Adaptation pour GW-BASIC : D. Rioual avril 2020
      18 REM
      17 REM ************************************************
      10 REM
      20 REM Liste des variables
      21 REM *******************
      22 REM AO : Armoire Ouverte
      23 REM CO : Clef en OR
      24 REM CP : Clef Petite
      25 REM LA : LAmpe de poche
      26 REM LAA : LAmpe Allumee
      27 REM MCH : Monte-charge Haut
      28 REM MCB : Monte-charge Bas
      29 REM Z : Compteur
      30 REM
      40 REM ***** Constantes *****
      50 AF1$ = CHR$(10)
      55 A$=” D’accord”
      60 COLDES = 11 : REM Couleur du texte de description
      70 COLOPT = 12 : REM Couleur du texte d’affichage des options
      80 COLINP = 14 : REM Couleur de la saisie operateur
      90 VETES$=”Vous “+CHR$(136)+”tes “
      100 DIM B$(21)
      105 GOSUB 12000 : REM Init des options du joueur
      110 GOSUB 10000 : REM Affiche l’intro
      120 CLS
      130 PRINT:PRINT:PRINT TAB(10);:COLOR 0,7: PRINT ” INSTRUCTIONS POUR EXECUTER UNE ACTION “
      135 COLOR COLOPT,0:PRINT:PRINT TAB(14) CHR$(28)”Entrez le nombre qui se trouve devant l’action.”
      140 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:COLOR COLINP:PRINT “Appuyez sur CR pour continuer”
      150 K$ = INPUT$(1) : COLOR COLDES:CLS
      160 COLOR COLDES:PRINT AF1$;VETES$;”devant une vieille maison abandonn”+CHR$(130);”e.”:PRINT:PRINT
      165 COLOR COLOPT:PRINT B$(10):PRINT B$(11):PRINT B$(12):PRINT
      170 GOSUB 11000 : REM Saisie du choix du joueur
      180 IF INT(I)<>I OR I<10 THEN GOTO 170
      190 ON I-9 GOTO 191,191,200:GOTO 170
      191 PRINT AF1$;”Vous avez raison,la curiosit”;CHR$(130);” est un vilain d”;CHR$(130);”faut.”
      192 END
      200 PRINT AF1$;”La porte se referme derri”;CHR$(138);”re vous, impossible de l’ouvrir.”
      201 TEMPO=3 : GOSUB 11100 : REM Attente de 3 secondes
      220 PRINT AF1$;VETES$;”dans l’entr”+CHR$(130);”e,il y a une porte “;CHR$(133);” l’est et “;CHR$(133);” l’ouest.”
      230 COLOR COLOPT:PRINT:PRINT B$(3):PRINT B$(4):PRINT
      231 GOSUB 11000
      232 IF INT(I)<>I OR I<3 THEN GOTO 231
      233 ON I-2 GOTO 250,650:GOTO 231
      250 PRINT AF1$;VETES$;”dans un hall,il y a une porte au nord et “;CHR$(133);” l’ouest”
      251 PRINT”et des escaliers qui montent “;CHR$(133);” l’est.”
      260 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(4):PRINT B$(5):PRINT
      261 GOSUB 11000
      262 IF INT(I)<>I OR I<1 THEN GOTO 261
      263 ON I GOTO 300,261,261,220,350:GOTO 261
      300 PRINT AF1$;VETES$;”dans une penderie, il y a une porte “;CHR$(133);” l’est, au nord”
      301 PRINT”et au sud.”
      310 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(3):PRINT
      311 GOSUB 11000
      312 IF INT(I)<>I OR I<1 THEN GOTO 311
      313 ON I GOTO 1300,250,500:GOTO 311
      350 PRINT AF1$;VETES$;”dans un long couloir,il y a 3 portes “;CHR$(133);” l’est : une au”
      351 PRINT”nord,une au centre et une au sud. Il y a 3 portes “;CHR$(133);” l’ouest : une au”
      352 PRINT”nord,une au centre et une au sud. Il y a aussi une porte au nord et au”
      353 PRINT”sud et des escaliers qui descendent “;CHR$(133);” l’ouest.”
      354 PRINT”Il y a aussi un monte-charges avec un bouton Mont”;CHR$(130);”e et un bouton”
      355 PRINT”Descente.”
      356 IF MCH=0 THEN GOTO 360
      357 PRINT”Le plateau du monte-charges est l”;CHR$(133);”.”
      358 IF CO=0 THEN PRINT”Il y a une clef en OR.”
      359 GOTO 361
      360 PRINT”Le plateau du monte-charges n’est pas l”;CHR$(133);”.”
      361 COLOR COLOPT:PRINT:IF MCH=1 AND CO=0 THEN PRINT B$(21)
      362 Z=Z+1
      364 PRINT B$(1):PRINT B$(2):PRINT B$(6):PRINT B$(13):PRINT B$(14):PRINT B$(15)
      365 PRINT B$(16):PRINT B$(17):PRINT B$(18):PRINT B$(19):PRINT B$(20):PRINT
      366 GOSUB 11000
      367 IF INT(I)<>I OR I<1 THEN GOTO 366
      368 ON I GOTO 600,370,366,366,366,250:IF I<13 THEN GOTO 366
      369 ON I-12 GOTO 1200,1220,400,1240,1260,1280,379,377,373:GOTO 366
      370 PRINT AF1$;”Impossible, la porte ne s’ouvre pas.”
      371 IF CP=1 OR CO=1 THEN GOTO 380
      372 TEMPO=1.5:GOSUB 11100:GOTO 350
      373 IF MCH=0 OR CO=1 THEN GOTO 366
      374 PRINT:PRINT A$:CO=1
      375 TEMPO=1.5:GOSUB 11100:GOTO 350
      377 PRINT:PRINT A$:MCH=0:MCB=1:GOTO 375
      379 PRINT:PRINT” Impossible, le bouton ne s’enfonce pas.”:GOTO 375
      380 COLOR COLOPT:PRINT:IF CO=1 THEN PRINT” 1. Vous ouvrez avec votre clef en OR”
      381 IF CP=1 THEN PRINT” 2. Vous ouvrez avec votre petite clef”
      382 PRINT” 3. Vous retournez dans le couloir”
      383 PRINT:GOSUB 11000
      384 IF INT(I)<>I OR I<1 OR I>3 THEN GOTO 383
      385 ON I GOTO 386,390,350
      386 IF CO=0 THEN GOTO 383
      387 PRINT:PRINT”Impossible,elle n’entre pas dans la serrure.”
      388 TEMPO=1.5:GOSUB 11100:GOTO 383
      390 IF CP=0 THEN GOTO 383
      391 PRINT:PRINT”La clef ouvre la porte, mais vous decouvrez un mur derri”;CHR$(138);”re elle.”
      392 GOTO 388
      400 PRINT AF1$;VETES$;”dans une petite pi”;CHR$(138);”ce, il y a des escaliers qui”
      401 PRINT”montent au nord, une porte “;CHR$(133);” l’ouest et une “;CHR$(133);” l’est.”
      410 COLOR COLOPT:PRINT:PRINT B$(3):PRINT B$(4):PRINT B$(5):PRINT
      411 GOSUB 11000
      412 IF INT(I)<>I OR I<3 THEN GOTO 411
      413 ON I-2 GOTO 415,350,950:GOTO 411
      415 PRINT AF1$;”En appuyant sur la clanche, vous ouvrez une trappe sous vos”
      416 PRINT”pieds et vous tombez dans un trou profond.”
      417 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB(30)”VOUS MOUREZ !”
      418 END
      450 PRINT AF1$;VETES$;”dans un grand garage, il y a une porte “;CHR$(133);” l’est et”
      451 PRINT”au nord.”
      452 PRINT”Il y a aussi un disjoncteur avec une inscription : ligne HT du toit.”
      453 PRINT”A c”;CHR$(147);”t”;CHR$(130);”, il y a un bouton vert et un bouton rouge.”
      460 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(8):PRINT B$(9):PRINT
      461 GOSUB 11000
      462 IF INT(I)<>I OR I<1 THEN GOTO 461
      463 ON I GOTO 1050,461,700,461,461,461,461,467,469:GOTO 461
      467 PRINT:PRINT A$:HT=0:GOTO 461
      469 PRINT:PRINT A$:HT=1:GOTO 461
      500 PRINT AF1$;VETES$;”dans un petit couloir, il y a une porte “;CHR$(133);” l’est,”
      501 PRINT”une “;CHR$(133);” l’ouest et une au nord”
      510 PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(4):PRINT
      511 GOSUB 11000
      512 IF INT(I)<>I OR I<1 THEN GOTO 511
      513 ON I GOTO 1100,511,550,300:GOTO 511
      550 PRINT AF1$;VETES$;”dans une cuisine, il y a une porte “;CHR$(133);” l’est,une “;CHR$(133);””
      551 PRINT”l’ouest et une au nord.”
      552 PRINT”Il y a aussi un monte-charges, un bouton Mont”;CHR$(130);”e et un bouton Descente.”
      553 IF MCB=0 THEN GOTO 557
      554 PRINT”Le plateau du monte-charges est l”;CHR$(133);”.”
      555 IF CO=0 THEN PRINT”Il y a une clef en OR.”
      556 GOTO 558
      557 PRINT”Le plateau du monte-charges n’est pas l”;CHR$(133);”.”
      558 COLOR COLOPT:PRINT:IF MCB=1 AND CO=0 THEN PRINT B$(21)
      560 PRINT B$(1):PRINT B$(3):PRINT B$(4):PRINT B$(19):PRINT B$(20):PRINT
      561 GOSUB 11000
      562 IF INT(I)<>I OR I<1 THEN GOTO 561
      563 ON I GOTO 1300,561,1000,500:IF I<19 THEN GOTO 561
      564 ON I-18 GOTO 570,573,565:GOTO 561
      565 IF MCB=0 OR CO=1 THEN GOTO 561
      566 PRINT:PRINT A$:CO=1
      567 TEMPO=1.5:GOSUB 11100:GOTO 550
      570 PRINT:PRINT A$:MCB=0:MCH=1:GOTO 567
      573 PRINT:PRINT” Impossible, le bouton ne s’enfonce pas.”:GOTO 567
      600 PRINT AF1$;VETES$;”dans une chambre, il y a une porte “;CHR$(133);” l’ouest et”
      601 PRINT”au sud et des escaliers qui descendent “;CHR$(133);” l’est.”
      610 COLOR COLOPT:PRINT:PRINT B$(2):PRINT B$(4):PRINT B$(6):PRINT
      611 GOSUB 11000
      612 IF INT(I)<>I OR I<2 THEN GOTO 611
      613 ON I-1 GOTO 350,611,850,611,800:GOTO 611
      650 PRINT AF1$;VETES$;”dans une petite pi”;CHR$(138);”ce, il y a une porte “;CHR$(133);” l’est et”
      651 PRINT”une au nord et des escaliers qui descendent “;CHR$(133);” l’ouest.”
      660 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(6):PRINT
      661 GOSUB 11000
      662 IF INT(I)<>I OR I<1 THEN GOTO 661
      663 ON I GOTO 750,661,220,661,661,700:GOTO 661
      700 PRINT AF1$;VETES$;”dans un couloir, il y a des escaliers qui montent”
      701 PRINT””;CHR$(133);” l’est,une porte “;CHR$(133);” l’est,une “;CHR$(133);” l’ouest et une au nord.”
      705 Z=Z+2
      710 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(4):PRINT B$(5):PRINT
      711 GOSUB 11000
      712 IF INT(I)<>I OR I<1 THEN GOTO 711
      713 ON I GOTO 1000,711,900,450,650:GOTO 711
      750 PRINT AF1$;VETES$;”dans un grand salon, il y a une porte au sud et”
      751 PRINT”une “;CHR$(133);” l’est. Il y a aussi un bar dans le coin nord-ouest.”
      759 COLOR COLOPT:PRINT:PRINT” 1 Vous allez au bar pour vous d”;CHR$(130);”salterer.”
      760 PRINT B$(2):PRINT B$(3):PRINT
      761 GOSUB 11000
      762 IF INT(I)<>I OR I<1 THEN GOTO 761
      763 ON I GOTO 764,650,1100:GOTO 761
      764 IF CP=1 THEN GOTO 773
      765 PRINT”Au milieu des bouteilles, vous voyez une petite clef.”
      766 COLOR COLINP:PRINT:PRINT”Vous la prenez(1) ou pas(0) “;
      767 INPUT I : COLOR COLDES
      768 IF I=1 THEN GOTO 771
      769 IF I<>0 THEN GOTO 767
      770 PRINT:PRINT A$:GOTO 772
      771 PRINT:PRINT A$:CP=1
      772 TEMPO=1:GOSUB 11100:GOTO 750
      773 PRINT:PRINT”Vous choisissez une des nombreuses bouteilles pour vous”
      774 PRINT”d”;CHR$(130);”salterer.”
      775 TEMPO=1.5:GOSUB 11100:GOTO 750
      800 PRINT AF1$;VETES$;”dans un couloir,il y a des escaliers qui montent”
      801 PRINT””;CHR$(133);” l’ouest,une porte au sud et une “;CHR$(133);” l’est.”
      810 COLOR COLOPT:PRINT:PRINT B$(2):PRINT B$(3):PRINT B$(5):PRINT
      811 GOSUB 11000
      812 IF INT(I)<>I OR I<2 THEN GOTO 811
      813 ON I-1 GOTO 900,1300,811,600:GOTO 811
      850 PRINT AF1$;VETES$;”dans une salle de bains, il y a une porte “;CHR$(133);””
      851 PRINT”l’ouest, une “;CHR$(133);” l’est et une au sud.”
      860 COLOR COLOPT:PRINT:PRINT B$(2):PRINT B$(3):PRINT B$(4):PRINT
      861 GOSUB 11000
      862 IF INT(I)<>I OR I<2 THEN GOTO 861
      863 ON I-1 GOTO 1100,600,1150:GOTO 861
      900 PRINT AF1$;VETES$;”dans une salle de projection, il y a une porte”
      901 PRINT”au nord, une au sud et une “;CHR$(133);” l’ouest.”
      910 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(4):PRINT
      911 GOSUB 11000
      912 IF INT(I)<>I OR I<1 THEN GOTO 911
      913 ON I GOTO 800,1000,911,700:GOTO 911
      950 PRINT AF1$;VETES$;”sur un toit plat, une barri”;CHR$(138);”re “;CHR$(130);”lectrique H.T.”
      951 PRINT”en fait le tour et des escaliers en descendent au sud.”
      960 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(3):PRINT B$(4):PRINT B$(6):PRINT
      961 GOSUB 11000
      962 IF INT(I)<>I OR I<1 THEN GOTO 961
      963 ON I GOTO 964,964,964,964,961,400:GOTO 961
      964 IF HT=1 THEN GOTO 966
      965 PRINT AF1$;”Vous vous “;CHR$(130);”lectrocutez.”:GOTO 417
      966 PRINT:PRINT”Il y a des pointes sur le mur qui entoure la maison.”
      967 COLOR COLOPT:PRINT:PRINT” 1. Vous sautez du toit en prenant de nombreux risques.”
      968 PRINT B$(6):PRINT
      969 GOSUB 11000
      970 IF I=6 THEN GOTO 400
      971 IF I<>1 THEN GOTO 969
      972 IF Z=10 THEN GOTO 975
      973 PRINT AF1$;”Vous tombez sur les pointes qui entourent la maison.”
      974 GOTO 417
      975 PRINT AF1$;”Vous avez eu de la chance, votre saut a “;CHR$(130);”t”;CHR$(130);” assez important”
      976 PRINT”pour franchir les pointes. Malheureusement, vous vous “;CHR$(136);”tes casse la”
      977 PRINT”jambe en tombant mal.”
      978 PRINT”Enfin, vous vous en “;CHR$(136);”tes sorti et c’est le principal.”
      979 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB(30)”BRAVO !”
      980 END
      1000 PRINT AF1$;VETES$;”dans un auditorium, il y a une porte au nord,”
      1001 PRINT”une au sud et une “;CHR$(133);” l’ouest.”
      1010 PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(4):PRINT
      1011 GOSUB 11000
      1012 IF INT(I)<>I OR I<1 THEN GOTO 1011
      1013 ON I GOTO 900,700,1011,550:GOTO 1011
      1050 PRINT AF1$;VETES$;”dans un atelier. Il y a une porte au sud.”
      1060 COLOR COLOPT:PRINT:PRINT B$(2):PRINT
      1061 GOSUB 11000
      1062 IF I=2 THEN GOTO 450 ELSE GOTO 1061
      1100 PRINT AF1$;VETES$;”sur un escalier, il y a une porte en haut au nord”
      1101 PRINT”et 2 portes en bas : au sud et “;CHR$(133);” l’ouest.”
      1110 COLOR COLOPT:PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(4):PRINT
      1111 GOSUB 11000
      1112 IF INT(I)<>I OR I<1 THEN GOTO 1111
      1113 ON I GOTO 850,500,1111,750:GOTO 1111
      1150 PRINT AF1$;VETES$;”dans une chambre o”;CHR$(151);” il y a une porte “;CHR$(133);” l’est.”
      1152 PRINT”Il y a aussi une armoire “;CHR$(133);” l’ouest.”
      1153 IF A0=0 THEN GOTO 1159
      1154 PRINT”L’armoire est ouverte.”
      1155 COLOR COLOPT:PRINT:PRINT” 1.Vous regardez dans l’armoire”
      1156 GOTO 1160
      1159 PRINT:PRINT” 1 Vous essayez d’ouvrir l’armoire”
      1160 PRINT B$(3):PRINT
      1161 GOSUB 11000
      1162 IF I=3 THEN GOTO 850
      1163 IF I<>1 THEN GOTO 1161
      1165 IF A0=1 THEN GOTO 1320
      1166 PRINT:PRINT”Impossible de l’ouvrir”
      1167 IF CO=0 AND CP=0 THEN GOTO 1161
      1168 COLOR COLOPT:PRINT:IF CO=1 THEN PRINT” 1. Vous essayez d’ouvrir la porte avec votre clef en OR”
      1169 IF CP=1 THEN PRINT” 2. Vous essayez d’ouvrir la porte avec votre petite clef”
      1170 PRINT B$(3):PRINT
      1171 GOSUB 11000
      1172 IF INT(I)<>I OR I<1 THEN GOTO 1171
      1173 ON I GOTO 1319,1174,850:GOTO 1171
      1174 IF CP=0 THEN GOTO 1171
      1175 PRINT AF1$;”Impossible de l’ouvrir,la clef ne convient pas.”
      1176 TEMPO=1.5:GOSUB 11100:GOTO 1150
      1200 PRINT AF1$;VETES$;”dans une chambre. Il y a une porte “;CHR$(133);” l’ouest.”
      1201 PRINT”Il y a aussi un t”;CHR$(130);”l”;CHR$(130);”phone sur une table.”
      1210 COLOR COLOPT:PRINT:PRINT B$(4):PRINT” 5. Vous essayez d’appeler police-secours.”:PRINT
      1211 GOSUB 11000
      1212 IF I=4 THEN GOTO 350
      1213 IF I<>5 THEN GOTO 1211
      1214 PRINT:PRINT”En d”;CHR$(130);”crochant le t”;CHR$(130);”l”;CHR$(130);”phone,vous n’entendez aucune tonalit”;CHR$(130);”.”
      1215 PRINT”En regardant sous la table, vous voyez que les fils sont arrach”;CHR$(130);”s.”
      1216 TEMPO=3:GOSUB 11100:GOTO 1200
      1220 PRINT AF1$;VETES$;”dans une chambre, il y a une porte “;CHR$(133);” l’ouest.”
      1221 PRINT”Il y a aussi une commode avec 6 tiroirs.”
      1225 COLOR COLOPT:PRINT:PRINT B$(4):PRINT” 5. Vous cherchez dans les tiroirs”:PRINT
      1226 GOSUB 11000
      1227 IF I=4 THEN GOTO 350
      1228 IF I<>5 THEN GOTO 1226
      1229 IF LA=0 THEN GOTO 1231
      1230 PRINT:PRINT A$:GOTO 1226
      1231 PRINT:PRINT”En ouvrant le tiroir en bas a droite, vous trouvez une lampe “
      1232 PRINT”de poche.”:COLOR COLOPT:PRINT:PRINT”Vous la prenez(1) ou pas(2) “
      1233 PRINT:GOSUB 11000
      1234 IF I=1 THEN GOTO 1238
      1235 IF I<>2 THEN GOTO 1233
      1236 PRINT:PRINT A$
      1237 TEMPO=1.5:GOSUB 11100:GOTO 1220
      1238 PRINT:PRINT A$:LA=1:GOTO 1237
      1240 PRINT AF1$;VETES$;”dans une chambre, il y a une porte “;CHR$(133);” l’est.”
      1250 COLOR COLOPT:PRINT:PRINT B$(3):PRINT B$(7):PRINT
      1251 GOSUB 11000
      1252 IF I=3 THEN GOTO 350
      1253 IF I<>7 THEN GOTO 1251
      1254 TEMPO=5:GOSUB 11100:GOTO 1251
      1260 PRINT AF1$;VETES$;”dans une salle de bains, il y a une porte “;CHR$(133);” l’est.”
      1270 COLOR COLOPT:PRINT:PRINT B$(3):PRINT B$(7):PRINT
      1271 GOSUB 11000
      1272 IF I=3 THEN GOTO 350
      1273 IF I<>7 THEN GOTO 1271
      1274 TEMPO=5:GOSUB 11100:GOTO 1271
      1280 PRINT AF1$;VETES$;”devant les WC, vous pouvez soit entrer vous”
      1281 PRINT:PRINT”soulager(1) ou rester dans le couloir(0).”
      1285 PRINT:GOSUB 11000
      1286 IF I=0 THEN GOTO 350
      1287 IF I<>1 THEN GOTO 1285
      1288 PRINT AF1$;”En entrant dans les WC,vous pouvez lire ce message sur la”
      1289 PRINT”porte : IL FAUT BEAUCOUP D’AMPOULES POUR ECLAIRER NEW-YORK,”
      1290 PRINT” MAIS UNE LAMPE DE POCHE PERMET DE SORTIR DE CETTE MAISON.”
      1291 TEMPO=5:GOSUB 11100
      1292 PRINT AF1$;”Vous retournez dans le couloir apr”;CHR$(138);”s vous “;CHR$(136);”tre soulag”;CHR$(130);”.”
      1293 TEMPO=2:GOSUB 11100:GOTO 350
      1300 PRINT AF1$;VETES$;”dans une salle-“;CHR$(133);”-manger,il y a une porte “;CHR$(133);””
      1301 PRINT”l’ouest et 2 au sud : une “;CHR$(133);” l’est et une “;CHR$(133);” l’ouest.”
      1310 COLOR COLOPT:PRINT:PRINT B$(4):PRINT B$(15):PRINT B$(18):PRINT
      1311 GOSUB 11000
      1312 IF INT(I)<>I OR I<4 THEN GOTO 1311
      1313 ON I-4 GOTO 800:IF I<15 THEN GOTO 1311
      1314 ON I-14 GOTO 550,1311,1311,300:GOTO 1311
      1319 IF CO=0 THEN GOTO 1171:A0=1
      1320 PRINT AF1$;”Derri”;CHR$(138);”re le faux fond de l’armoire se trouve une grotte”
      1321 PRINT”sombre. Des bruits “;CHR$(130);”tranges d’animaux sauvages vous font tressaillir.”
      1322 PRINT”Mais,le jour vois apparait d”;CHR$(130);”ja l”;CHR$(133);”-bas, tout au fond de la grotte.”
      1328 COLOR COLOPT:PRINT:PRINT” 1 Vous avancez”:PRINT” 2 Vous retournez dans la chambre.”
      1329 IF LA=1 AND LAA=0 THEN PRINT” 3 Vous allumez la lampe de poche”
      1330 GOSUB 11000
      1331 IF INT(I)<>I OR I<1 THEN GOTO 1330
      1332 ON I GOTO 1333,1150,1350:GOTO 1330
      1333 IF LAA=1 THEN GOTO 1335
      1334 PRINT AF1$;”Vous tombez dans un trou.”:GOTO 417
      1335 PRINT AF1$;”Vous voyez appara”;CHR$(140);”tre un trou devant vous que vous contournez.”
      1336 TEMPO=3:GOSUB 11100
      1337 PRINT:PRINT”Vous continuez ensuite d’avancer. Les rats vous font encore”
      1338 PRINT”quelques frayeurs.”
      1339 FOR I=1 TO 2500:NEXT I
      1340 PRINT:PRINT”Mais,finalement,le jour se rapproche et vous “;CHR$(136);”tes bient”;CHR$(147);”t libre”
      1341 TEMPO=1.5:GOSUB 11100
      1342 PRINT:PRINT”Ca y est,vous vous en “;CHR$(136);”tes tout de m”;CHR$(136);”me sorti.”
      1343 PRINT:PRINT:PRINT:PRINT:PRINT TAB(20)”TRIPLES BRAVOS !!!!!!!!!!!!!”
      1344 END
      1350 IF LA=0 THEN GOTO 1330
      1351 PRINT:PRINT A$
      1352 FOR I=1 TO 1500:NEXT I:LAA=1:GOTO 1320
      9999 REM INTRO
      10000 SCREEN 0:CLS
      10005 KEY OFF
      10010 COLOR 14,0 :PRINT STRING$(29,”_”);” LA MAISON DU FOU “;STRING$(29,”_”)
      10020 COLOR 10,0
      10098 REM ———- 1 2 3 4 5 6 7
      10099 REM ———-3456789012345678901234567890123456789012345678901234567890123456789012
      10100 PRINT TAB(3);” |”
      10110 PRINT TAB(3);” * * , * \ /”
      10120 PRINT TAB(3);” * * ) — * –“
      10130 PRINT TAB(3);” * .———–. (( / \”
      10140 PRINT TAB(3);” * * )`’`’`’`’`’`( || * |”
      10150 PRINT TAB(3);” /`’`’`’`’`’`’`\|| *”
      10160 PRINT TAB(3);” * * * /`’`’`’`’`’`’`’`\| * *”
      10170 PRINT TAB(3);” ,,,,,,, /`’`’`’`’`’`’`’`’`\ ,”
      10180 PRINT TAB(3);” * .——-.`|“““““““`|` . ) * *”
      10190 PRINT TAB(3);” * * / ,^, ,^, \| ,^^, ,^^, | / \ ((“
      10200 PRINT TAB(3);” / |_| |_| \ |__| |__| | / \|| *”
      10210 PRINT TAB(3);” * * /_____________\ | | | | |/ \| *”
      10220 PRINT TAB(3);” | __ __ | ‘==’ ‘==’ /…….\ *”
      10230 PRINT TAB(3);” * * | ( ) ( ) | //`_“`_`\\ |,^, ,^,| _ *”
      10240 PRINT TAB(3);” | |–| |–| | ||(O)|(O)|| ||_| |_|| “
      10250 PRINT TAB(3);” * | |__| |__| | || ‘ | ‘ || ||_| |_|| * *”
      10260 PRINT TAB(3);” | | || | || | | *”
      10270 PRINT TAB(3);” ****************’===========’==”===’===”==’=======’***************”
      10300 COLOR 12
      10305 PRINT
      10310 PRINT ” Auteurs: DIEUDONNE P. NOEL H. Magazine MICRO 7 mars 1984″
      10320 PRINT ” Adaptation IMB PC : RIOUAL D. Avril 2020″
      10330 REM Affiche d’etoiles clignotantes
      10340 RESTORE 20000
      10350 FOR I = 1 TO 30
      10360 COL = INT(RND(1)*15) + 17 : COLOR COL
      10370 READ X,Y
      10375 IF X<0 OR Y<0 THEN GOTO 10400
      10380 LOCATE Y,X : PRINT “*”
      10390 NEXT
      10400 LOCATE 24,23:COLOR 2:PRINT “Pressez une touche pour commencer.”;
      10410 K$ = INPUT$(1)
      10420 COLOR 7
      10430 RETURN
      10999 REM GOSUB et fonctions
      11000 REM ***** Saisie d’un choix du joueur *****
      11010 COLOR COLINP : INPUT”Que faites-vous “;I
      11020 COLOR COLDES
      11030 RETURN
      11100 REM ***** Attente de TEMPO secondes *****
      11110 T = TIMER
      11120 WHILE TIMER < T + TEMPO
      11130 WEND
      11140 RETURN
      12000 REM ***** Init des options du joueur *****
      12010 B$(1)=” 1. Vous allez au nord”:B$(2)=” 2. Vous allez au sud”:B$(3)=” 3. Vous allez “+CHR$(133)+” l’est”
      12020 B$(4)= ” 4. Vous allez “+CHR$(133)+” l’ouest”:B$(5)=” 5. Vous montez les escaliers”
      12030 B$(6)= ” 6. Vous descendez les escaliers”
      12040 B$(7)= ” 7. Vous attendez”:B$(8)=” 8. Vous appuyez sur le bouton vert”
      12050 B$(9)= ” 9. Vous appuyez sur le bouton rouge”:B$(10)=”10. Vous ne faites rien”
      12060 B$(11)= “11. Vous partez”:B$(12)=”12. Vous entrez dans la maison”
      12070 B$(13)= “13. Vous allez au nord-est”:B$(14)=”14. Vous allez au centre-est”
      12080 B$(15)= “15. Vous allez au sud-est”:B$(16)=”16. Vous allez au nord-ouest”
      12090 B$(17)= “17. Vous allez au centre-ouest”:B$(18)=”18. Vous allez au sud-ouest”
      12100 B$(19)= “19. Vous appuyez sur le bouton Mont”+CHR$(130)+”e du monte-charges”
      12110 B$(20)= “20. Vous appuyez sur le bouton Descente du monte-charges”
      12120 B$(21)= “21. Vous prenez la clef”
      12130 RETURN
      20000 REM DATA
      20010 REM DATA pour l’intro, position des etoiles clignotantes
      20020 DATA 35,3, 45,3, 55,3 : DATA 17,4, 40,4 : DATA 22,5 : DATA 11,6, 28,6, 55,6
      20021 DATA 71,7 : DATA 7,8, 17,8, 24,8 : DATA 7,8, 17,8, 24,8, 51,8, 60,8
      20040 DATA -1,-1
      20100 REM DATA des options du joueur
    • Author
      Posts
    Viewing 1 post (of 1 total)
    • You must be logged in to reply to this topic.